<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="creationComplete();">
	<mx:Script>
		<![CDATA[
			import mx.core.UIComponent;
 
			/**
			 * @private
			 * Listen to mouse movements.
			 */
			private function creationComplete():void
			{
				addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
			}
 
			/**
			 * @private
			 * On each mouse move, evaluate the mouse cursor position
			 * to find the nearest child.
			 */
			private function mouseMoveHandler(event:MouseEvent):void
			{
				var closestDistance:Number;
				var closestChild:UIComponent;
 
				// Loop through children and find the child closest to the
				// mouse cursor.
				for each (var child:UIComponent in getChildren())
				{
					var distance:Number = getDistanceFromRect(
							event.stageX, event.stageY, child.getBounds(stage));
 
					if (isNaN(closestDistance) || distance < closestDistance)
					{
						closestDistance = distance;
						closestChild = child;
					}
				}
 
				trace('Closest Child: ' + UIComponent(closestChild).id);
			}
 
			/**
			 * @private
			 * Gets the distance between a point from a rectangle.  This doesn't evaluate the distance of
			 * the point from the center of the rectangle, but instead the distance of the point
			 * from the closest edge of the rectangle.
			 * 
			 * @param x The X coordinate of the point to be evaluated.
			 * @param y The Y coordinate of the point to be evaluated.
			 * @param rect The rectangle from which the distance will be measured to the point.
			 * 
			 * @return The distance in pixels between the point and the rectangle.
			 */
			private function getDistanceFromRect(x:Number, y:Number, rect:Rectangle):Number
			{
				// If the rectange contains the point we are evaluating, then there is
				// no distance between the point and the rectangle.
				if (rect.contains(x, y))
				{
					return 0;
				}
				else
				{
					// Retrieve distances to the closest edge.
					var xDist:Number = 0;
					var yDist:Number = 0;
 
					if (x < rect.left)
					{
						xDist = rect.left - x;
					}
					else if (x > rect.right)
					{
						xDist = x - rect.right;
					}
 
					if (y < rect.top)
					{
						yDist = rect.top - y;
					}
					else if (y > rect.bottom)
					{
						yDist = y - rect.bottom;
					}
 
					// Return the distance between the point and the nearest edge
					// using the Pythagorean theorem.
					return Math.sqrt(Math.pow(xDist, 2) + Math.pow(yDist, 2));
				}
			}
		]]>
	</mx:Script>
 
	<mx:Label id="topLeftLabel" text="Top-Left" top="10" left="10"/>
	<mx:Button id="bottomLeftButton" label="Bottom-Left" bottom="10" left="10"/>
	<mx:Text id="middleRightText" text="Middle-Right" verticalCenter="0" right="10"/>
 
</mx:Application>